Set FontFamily "Monoflow"

Set Width

Set the width of the terminal with the Set Width command.

Set Width 300

Set Height

Set the height of the terminal with the Set Height command.

Set Height 1000

Set Letter Spacing

Set the spacing between letters (tracking) with the Set LetterSpacing
Command.

Set LetterSpacing 20

Set Line Height

Set the spacing between lines with the Set LineHeight Command.

Set LineHeight 1.8

Set Typing Speed

Set TypingSpeed 500ms # 500ms
Set TypingSpeed 1s    # 1s

Set the typing speed of seconds per key press. For example, a typing speed of
0.1 would result in a 0.1s (100ms) delay between each character being typed.

This setting can also be overwritten per command with the @ syntax.

Set TypingSpeed 0.1
Type "100ms delay per character"
Type@500ms "500ms delay per character"

Set Theme

Set the theme of the terminal with the Set Theme command. The theme value
should be a JSON string with the base 16 colors and foreground + background.

Set Theme { "name": "Whimsy", "black": "#535178", "red": "#ef6487", "green": "#5eca89", "yellow": "#fdd877", "blue": "#65aef7", "magenta": "#aa7ff0", "cyan": "#43c1be", "white": "#ffffff", "brightBlack": "#535178", "brightRed": "#ef6487", "brightGreen": "#5eca89", "brightYellow": "#fdd877", "brightBlue": "#65aef7", "brightMagenta": "#aa7ff0", "brightCyan": "#43c1be", "brightWhite": "#ffffff", "background": "#29283b", "foreground": "#b3b0d6", "selection": "#3d3c58", "cursor": "#b3b0d6" }

You can also set themes by name:

Set Theme "Catppuccin Frappe"

See the full list by running vhs themes, or in THEMES.md.

Set Padding

Set the padding (in pixels) of the terminal frame with the Set Padding
command.

Set Padding 0

Set Margin

Set the margin (in pixels) of the video with the Set Margin command.

Set Margin 60
Set MarginFill "#6B50FF"

Set Window Bar

Set the type of window bar (Colorful, ColorfulRight, Rings, RingsRight) on the terminal window with the Set WindowBar command.

Set WindowBar Colorful

Set Border Radius

Set the border radius (in pixels) of the terminal window with the Set BorderRadius command.

# You'll likely want to add a Margin + MarginFill if you use BorderRadius.
Set Margin 20
Set MarginFill "#674EFF"
Set BorderRadius 10

Set Framerate

Set the rate at which VHS captures frames with the Set Framerate command.

Set Framerate 60

Set Playback Speed

Set the playback speed of the final render.

Set PlaybackSpeed 0.5 # Make output 2 times slower
Set PlaybackSpeed 1.0 # Keep output at normal speed (default)
Set PlaybackSpeed 2.0 # Make output 2 times faster

Set Loop Offset

Set the offset for when the GIF loop should begin. This allows you to make the
first frame of the GIF (generally used for previews) more interesting.

Set LoopOffset 5 # Start the GIF at the 5th frame
Set LoopOffset 50% # Start the GIF halfway through

Set Cursor Blink

Set whether the cursor should blink. Enabled by default.

Set CursorBlink false

Type

Use Type to emulate key presses. That is, you can use Type to script typing
in a terminal. Type is handy for both entering commands and interacting with
prompts and TUIs in the terminal. The command takes a string argument of the
characters to type.

You can set the standard typing speed with <code class="ra0-md-code">Set TypingSpeed</code>
and override it in places with a @time argument.

# Type something
Type "Whatever you want"

# Type something really slowly!
Type@500ms "Slow down there, partner."

Escape single and double quotes with backticks.

Type `VAR="Escaped"`

Keys

Key commands take an optional @time and optional repeat count for repeating
the key press every interval of .

Key[@<time>] [count]

Backspace

Press the backspace key with the Backspace command.

Backspace 18

Ctrl

You can access the control modifier and send control sequences with the Ctrl
command.

Ctrl+R

Enter

Press the enter key with the Enter command.

Enter 2

Arrow Keys

Press any of the arrow keys with the Up, Down, Left, Right commands.

Up 2
Down 2
Left
Right
Left
Right
Type "B"
Type "A"

Tab

Enter a tab with the Tab command.

Tab@500ms 2

Space

Press the space bar with the Space command.

Space 10

Page Up / Down

Press the Page Up / Down keys with the PageUp or PageDown commands.

PageUp 3
PageDown 5

Scroll Up / Down

Scroll the terminal viewport directly with ScrollUp and ScrollDown.
Both commands use the same optional @time and repeat count shape as other
repeatable key commands: ScrollUp[@] [count].

ScrollUp 10
ScrollDown 4
ScrollDown@100ms 12

Wait

The Wait command allows you to wait for something to appear on the screen.
This is useful when you need to wait on something to complete, even if you don't
know how long it'll take, while including it in the recording like a spinner or
loading state.
The command takes a regular expression as an argument, and optionally allows you
to set the duration to wait and if you want to check the whole screen or just the
last line (the scope).

Wait
Wait            /World/
Wait+Screen     /World/
Wait+Line       /World/
Wait@10ms       /World/
Wait+Line@10ms  /World/

The default regular expression is />$/, the wait timeout is 15s, and the
default scope is Line.

Sleep

The Sleep command allows you to continue capturing frames without interacting
with the terminal. This is useful when you need to wait on something to
complete while including it in the recording like a spinner or loading state.
The command takes a number argument in seconds.

Sleep 0.5   # 500ms
Sleep 2     # 2s
Sleep 100ms # 100ms
Sleep 1s    # 1s

Hide

The Hide command instructs VHS to stop capturing frames. It's useful to pause
a recording to perform hidden commands.

Hide

This command is helpful for performing any setup and cleanup required to record
a GIF, such as building the latest version of a binary and removing the binary
once the demo is recorded.

Output example.gif

# Setup
Hide
Type "go build -o example . && clear"
Enter
Show

# Recording...
Type 'Running ./example'
...
Enter

# Cleanup
Hide
Type 'rm example'
Enter

Show

The Show command instructs VHS to begin capturing frames, again. It's useful
after a Hide command to resume frame recording for the output.

Hide
Type "You won't see this being typed."
Show
Type "You will see this being typed."

Screenshot

The Screenshot command captures the current frame (png format).

# At any point...
Screenshot examples/screenshot.png

Copy / Paste

The Copy and Paste copy and paste the string from clipboard.

Copy "https://github.com/charmbracelet"
Type "open "
Sleep 500ms
Paste

Env

Env command sets the environment variable via key-value pair.

Env HELLO "WORLD"

Type "echo $HELLO"
Enter
Sleep 1s

Source

The source command allows you to execute commands from another tape.

Source config.tape

Continuous Integration

You can hook up VHS to your CI pipeline to keep your GIFs up-to-date with
the official VHS GitHub Action:

> ⚙️ charmbracelet/vhs-action

VHS can also be used for integration testing. Use the .txt or .ascii output
to generate golden files. Store these files in a git repository to ensure there
are no diffs between runs of the tape file.

Output golden.ascii

Syntax Highlighting

There’s a tree-sitter grammar for .tape files available for editors that
support syntax highlighting with tree-sitter:

> 🌳 charmbracelet/tree-sitter-vhs

It works great with Neovim, Emacs, and so on!

Contributing

See [contributing][contribute].

[contribute]: https://github.com/charmbracelet/vhs/contribute

Feedback

We’d love to hear your thoughts on this project. Feel free to drop us a note!

• Twitter
• The Fediverse
• Discord

License

MIT

Part of Charm.

Charm热爱开源 • Charm loves open source